«
»

La classe Vector en ActionScript 3


La classe Vector : un tableau d'éléments de même type en AS3.

Introduction

La classe Vector vous permet d'accéder à un vecteur et de le manipuler; un vecteur est un tableau dont les éléments possèdent tous le même type de données.

Le type de données des éléments d'un vecteur est appelé le type de base. Le type de base peut correspondre à n'importe quelle classe ou interface.

Création d'une occurrence de Vector

Le type de base est spécifié lorsque vous déclarez la variable d'un vecteur. La syntaxe utilisée est Vector.<T> où T représente le type de base.

COPIER-COLLER
Actionscript:
  1. var trimestre:Vector.;

Le type de base est aussi spécifié lors de l'appel au constructeur Vector.<T>()

COPIER-COLLER
Actionscript:
  1. var trimestre:Vector.<String>;
  2.  trimestre = new Vector.<String>();

Un vecteur peut possèder une longueur fixe et donc avoir un nombre d'éléments invariables. Le constructeur de la classe Vector possède deux arguments optionnels : la longueur initiale du vecteur dont la valeur par défaut est 0 et un booléen indiquant si cette longueur est fixe, dont la valeur par défaut est false.

COPIER-COLLER
Actionscript:
  1. var trimestre:Vector.<String>;
  2. trimestre = new Vector.<String>(4, true);

Manipuler un vector

La manipulation d'un vecteur se fait en utilisant l'opérateur d'accès au tableau ([]) mais aussi en utilisant des méthodes identiques à la classe Array. Parmi ces méthodes, on retrouve : push(), pop(), shift(), unshift().

L'opérateur d'accès au tableau ([])

Il permet de définir ou de récupérer une valeur du vecteur.

COPIER-COLLER
Actionscript:
  1. var trimestre:Vector.<String>;
  2. trimestre = new Vector.<String>(4, true);
  3. trimestre[0] = "Janvier-Mars";
  4. trimestre[1] = "Avril-Juin";
  5. trimestre[2] = "Juillet-Septembre";
  6. trimestre[3] = "Octobre-Décembre";
  7. trace("1ère ligne du tableau : " + trimestre[0]);//1ère ligne du tableau : Janvier-Mars
  8. trace(trimestre);//Janvier-Mars,Avril-Juin,Juillet-Septembre,Octobre-Décembre

La méthode push()

La méthode push() ajoute un ou plusieurs éléments à la fin d'un vecteur.

COPIER-COLLER
Actionscript:
  1. var mois:Vector.<String>;
  2. mois = new Vector.<String>();
  3. mois.push("Janvier", "Février", "Mars", "Avril");
  4. trace(mois);

Cette méthode renvoie la nouvelle longueur du vecteur.

COPIER-COLLER
Actionscript:
  1. var mois:Vector.<String>;
  2. mois = new Vector.<String>();
  3. trace("Nombre d'éléments dans le vecteur avant l'ajout : " + mois.length);
  4. var nbElementsApresAjout:int = mois.push("Janvier", "Février", "Mars", "Avril");
  5. trace("Nombre d'éléments dans le vecteur après l'ajout : " + nbElementsApresAjout);

La méthode unshift()

La méthode unshift() ajoute un ou plusieurs éléments au début d'un vecteur et renvoie la nouvelle longueur du vecteur. Les autres éléments du vecteur sont décalés de leur position d'origine, n, vers n + le nombre de nouveaux éléments.

COPIER-COLLER
Actionscript:
  1. var duree:Vector.<int> = new Vector.<int>();
  2. var nbDuree:int = duree.push(15, 20, 25);
  3. trace("Nombre d'éléments dans le vecteur après l'ajout : " + nbDuree);
  4. nbDuree = duree.unshift(5, 10);
  5. trace("Nombre d'éléments dans le vecteur après l'ajout : " + nbDuree);
  6. trace(duree);

Bug pour les types String et Object

Avec un vecteur de type String ou Object, la méthode unshift() ajoute les éléments mais supprime un nombre identique d'éléments depuis la fin du vecteur.

COPIER-COLLER
Actionscript:
  1. var mois:Vector.<String>;
  2. mois = new Vector.<String>();
  3. trace("Nombre d'éléments dans le vecteur avant l'ajout : " + mois.length);
  4. var nbElements:int = mois.push("Mars", "Avril", "Mai", "Juin");
  5. trace("Nombre d'éléments dans le vecteur après l'ajout : " + nbElements);
  6. nbElements = mois.unshift("Janvier", "Février");
  7. trace("Nombre d'éléments dans le vecteur après l'ajout : " + nbElements);
  8. trace(mois);

Le bug est connu et répertorié : http://bugs.adobe.com/jira/browse/ASC-3620

La méthode pop()

La méthode pop() supprime le dernier élément du vecteur et renvoie cet élément. La propriété length du vecteur est diminuée d'une unité lorsque cette fonction est appelée.

COPIER-COLLER
Actionscript:
  1. var mois:Vector.<String>;
  2. mois = new Vector.<String>();
  3. trace("Nombre d'éléments dans le vecteur avant l'ajout : " + mois.length);
  4. var nbElements:int = mois.push("Janvier", "Février", "Mars", "Avril");
  5. trace("Nombre d'éléments dans le vecteur après l'ajout : " + nbElements);
  6. var elementSupprime:String = mois.pop();
  7. trace(elementSupprime + " a été supprimé du vecteur");
  8. trace("Nombre d'éléments dans le vecteur après la suppression : " + mois.length);

La méthode shift()

La méthode shift() supprime le premier élément du vecteur et renvoie cet élément. Les éléments restants du vecteur sont décalés de leur position d'origine, n, vers n -1.

COPIER-COLLER
Actionscript:
  1. var mois:Vector.<String>;
  2. mois = new Vector.<String>();
  3. trace("Nombre d'éléments dans le vecteur avant l'ajout : " + mois.length);
  4. var nbElements:int = mois.push("Janvier", "Février", "Mars", "Avril");
  5. trace("Nombre d'éléments dans le vecteur après l'ajout : " + nbElements);
  6. trace("Le premier élément avant la suppression est " + mois[0]);
  7. var elementSupprime:String = mois.shift();
  8. trace(elementSupprime + " a été supprimé du vecteur");
  9. trace("Le premier élément après la suppression est " + mois[0]);

La méthode splice()

La méthode splice() ajoute et supprime des éléments dans un vecteur. Cette méthode modifie le vecteur sans faire de copie.

Suppression d'éléments

splice(startIndex, deleteCount);

Cette méthode permet de supprimer des éléments à partir d'un index du vecteur. Le premier paramètre de la méthode correspond à l'index de départ, le deuxième paramètre correspond au nombre d'éléments à supprimer. Ce nombre inclut l'élément spécifié dans le paramètre startIndex

COPIER-COLLER
Actionscript:
  1. var mois:Vector.<String>;
  2. mois = new Vector.<String>();
  3. trace("Nombre d'éléments dans le vecteur avant l'ajout : " + mois.length);
  4. var nbElements:int = mois.push("Janvier", "Février", "Mars", "Avril", "Mai", "Juin");
  5. trace(mois)
  6. /*Suppression de Avril et Mai
  7. Avril a pour index : 3*/
  8. mois.splice(3, 2);
  9. trace(mois);

Ajout d'éléments

splice(startIndex, deleteCount, items);

Lors de l'ajout d'éléments, le paramètre startIndex indique la position à partir de laquelle l'insertion doit avoir lieu. Le paramètre deleteCount est défini avec une valeur à 0 afin de ne supprimer aucun élement. Le paramètre items représente une liste d'une ou de plusieurs valeurs séparées par une virgule.

COPIER-COLLER
Actionscript:
  1. var mois:Vector.<String>;
  2. mois = new Vector.<String>();
  3. trace("Nombre d'éléments dans le vecteur avant l'ajout : " + mois.length);
  4. var nbElements:int = mois.push("Janvier", "Février", "Mai", "Juin");
  5. trace(mois)
  6. mois.splice(2, 0, "Mars", "Avril");
  7. trace(mois);

Ajout et suppression d'éléments
COPIER-COLLER
Actionscript:
  1. var mois:Vector.<String>;
  2. mois = new Vector.<String>();
  3. mois.push("Janvier", "Février", "Mars", "Juin", "Juillet", "Août");
  4. trace(mois);
  5. mois.splice(3, 2, "Avril", "Mai");
  6. trace(mois);

Les erreurs associées à la classe Vector

L'erreur TypeError

Cette erreur est générée si un argument n'est pas une occurrence du type de base du vecteur.
Avec l'opérateur d'accès au tableau [], l'erreur est générée à la compilation.

COPIER-COLLER
Actionscript:
  1. var mois:Vector.<String>;
  2. mois = new Vector.<String>();
  3. mois[0] = 12;

Erreur1

Avec la méthode push(), cette erreur est générée à l'exécution.

COPIER-COLLER
Actionscript:
  1. var mois:Vector.<Sprite>;
  2. mois = new Vector.<Sprite>();
  3. mois.push("Janvier");
  4. trace(mois);

erreur2

L'erreur RangeError

Un vecteur est un tableau dense. Contrairement à un tableau, qui peut posséder des valeurs dans les index 0 et 7 même s'il n'existe aucune valeur dans les positions 1 à 6, un vecteur doit posséder une valeur (ou la valeur null) dans chaque index.

Cette erreur sera générée si vous essayez d'insérer une valeur dans un index en dehors des limites.

COPIER-COLLER
Actionscript:
  1. var mois:Vector.<String>;
  2. mois = new Vector.<String>();
  3. mois[0] = "Janvier";
  4. mois[1] = "Février";
  5. mois[5] = "Mars";
  6. trace(mois);

erreur3

Si vous avez défini un vecteur de taille fixe, cette erreur sera générée en utilisant les méthodes
push(), shift(), unshift().

COPIER-COLLER
Actionscript:
  1. var mois:Vector.<String>;
  2. mois = new Vector.<String>(4, true);
  3. mois.push("Janvier");
  4. trace(mois);

erreur4

Gestion des performances

L'opérateur d'accès au tableau [] vs la méthode push()

Lors de l'ajout d'une seule valeur à la fois, l'opérateur d'accès au tableau [] se montre plus rapide que la méthode push().

COPIER-COLLER
Actionscript:
  1. var v1:Vector.<String>;
  2. v1 = new Vector.<String>();
  3. var time1:int = getTimer();
  4. for(var i:int = 0; i<1000000; i++)
  5. {
  6. v1[i] = "i=" + i;
  7. }
  8. var time2:int = getTimer();
  9. trace("Temps d'exécution en millisecondes avec [] : " + (time2 - time1));
  10.  
  11. var v2:Vector.<String>;
  12. v2 = new Vector.<String>();
  13. var time3:int = getTimer();
  14. for(var j:int = 0; j<1000000; j++)
  15. {
  16. v2.push("j=" + j);
  17. }
  18. var time4:int = getTimer();
  19. trace("Temps d'exécution en millisecondes avec push() : " + (time4 – time3));

performances

Conclusion

Dans tous les cas où vous utilisez un objet Array dont tous les éléments possèdent le même type de données, il est préférable d'utiliser une occurrence de l'objet Vector.

Cependant, la classe Vector n'est disponible que pour Flash Player 10.

, , ,

Cet article a été posté le 30 mars 2009, 13:02 sous la catégorie Bases. Vous pouvez suivre les réponses à cet article via RSS 2.0.
Vous pouvez laisser un commentaire, ou un rétrolien depuis votre site.

  1. #1 by JeromeJ on 8 octobre 2009 - 22:31

    Salut, tu expliques ce qu'est la classe Vector, comment l'utiliser et quelles sont ses méthodes.
    Puis tu affirmes que, dans des cas précis, il est préférable de l'utiliser à la place de la classe Array.
    Mais tu n'expliques pas pourquoi, est-ce moins volumineux ? Plus rapide ? Certes il est plus strict mais est-ce tout ?
    (autrement dit: les seuls benchmarks faits sont à propos de différences internes à la classe elle même, mais pas de comparaison directe avec sa concurrente)

    C'est peut-être du à mon manque de culture en programmation (car il me semble que la classe Vector n'est pas née avec AS3) mais il est aussi fort probable que je ne sois pas le seul dans ce cas.

    Cordialement

    Citer

  2. #2 by tannoy on 9 octobre 2009 - 12:58

    Bonjour Jerome,

    Dans mon article, je ne dis qu'une seule fois qu'il est préférable de l’utiliser à la place de la classe Array.

    Dans tous les cas où vous utilisez un objet Array dont tous les éléments possèdent le même type de données, il est préférable d'utiliser une occurrence de l'objet Vector.

    Dans ce cas précis, je pense que la phrase est assez claire.

    D'autre part, le but de mon article n'était pas de comparer la classe Array a la classe Vector mais bien de présenter l'utilisation de la classe Vector.

    Concernant les benchmarks de cette classe, je te propose un article de Mike Chambers ainsi qu'un extrait en PDF du livre de Thibault Imbert (Page 28)

    ;-)

    Citer
(ne sera pas publié)